hokusai/flake.nix

{
  description = "hokusai - Bulk-Generate Images with Generative AI";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";

    pyproject-nix = {
      url = "github:pyproject-nix/pyproject.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    uv2nix = {
      url = "github:pyproject-nix/uv2nix";
      inputs.pyproject-nix.follows = "pyproject-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    pyproject-build-systems = {
      url = "github:pyproject-nix/build-system-pkgs";
      inputs.pyproject-nix.follows = "pyproject-nix";
      inputs.uv2nix.follows = "uv2nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    git-hooks = {
      url = "github:cachix/git-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      pyproject-nix,
      uv2nix,
      pyproject-build-systems,
      git-hooks,
      ...
    }:
    let
      inherit (nixpkgs) lib;
      forAllSystems = lib.genAttrs lib.systems.flakeExposed;

      workspace = uv2nix.lib.workspace.loadWorkspace { workspaceRoot = ./.; };

      overlay = workspace.mkPyprojectOverlay {
        sourcePreference = "wheel";
      };

      editableOverlay = workspace.mkEditablePyprojectOverlay {
        root = "$REPO_ROOT";
      };

      pythonSets = forAllSystems (
        system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
          inherit (pkgs) stdenv;

          baseSet = pkgs.callPackage pyproject-nix.build.packages {
            python = pkgs.python313;
          };

          pyprojectOverrides = _final: prev: {
            hokusai = prev.hokusai.overrideAttrs (old: {
              passthru = old.passthru // {
                tests = (old.passthru.tests or { }) // {
                  pytest = stdenv.mkDerivation {
                    name = "${_final.hokusai.name}-pytest";
                    inherit (_final.hokusai) src;
                    nativeBuildInputs = [
                      (_final.mkVirtualEnv "hokusai-pytest-env" {
                        hokusai = [ "dev" ];
                      })
                    ];
                    dontConfigure = true;
                    buildPhase = ''
                      runHook preBuild
                      # Exit code 5 means no tests collected — allow it so the
                      # check succeeds on an empty test suite.
                      pytest || [ $? -eq 5 ]
                      runHook postBuild
                    '';
                    installPhase = ''
                      runHook preInstall
                      touch $out
                      runHook postInstall
                    '';
                  };
                };
              };
            });
          };

        in
        baseSet.overrideScope (
          lib.composeManyExtensions [
            pyproject-build-systems.overlays.default
            overlay
            pyprojectOverrides
          ]
        )
      );

      mkGitHooksCheck =
        system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
          pythonSet = pythonSets.${system};
          venv = pythonSet.mkVirtualEnv "hokusai-check-env" workspace.deps.default;
        in
        git-hooks.lib.${system}.run {
          src = ./.;
          hooks = {
            basedpyright = {
              enable = true;
              entry = "${pkgs.basedpyright}/bin/basedpyright --pythonpath ${venv}/bin/python --project ${
                pkgs.writeText "pyrightconfig.json" (
                  builtins.toJSON {
                    reportMissingTypeStubs = false;
                    reportUnnecessaryTypeIgnoreComment = false;
                  }
                )
              }";
              files = "\\.py$";
              types = [ "file" ];
            };
            ruff.enable = true;
            ruff-format.enable = true;
            commitizen.enable = true;
          };
        };

    in
    {
      packages = forAllSystems (
        system:
        let
          pythonSet = pythonSets.${system};
          pkgs = nixpkgs.legacyPackages.${system};
          inherit (pkgs.callPackages pyproject-nix.build.util { }) mkApplication;
        in
        rec {
          hokusai = mkApplication {
            venv = pythonSet.mkVirtualEnv "hokusai-env" workspace.deps.default;
            package = pythonSet.hokusai;
          };
          default = hokusai;
        }
      );

      homeManagerModules = rec {
        hokusai = import ./nix/hm-module.nix self;
        default = hokusai;
      };

      checks = forAllSystems (
        system:
        let
          pythonSet = pythonSets.${system};
        in
        {
          inherit (pythonSet.hokusai.passthru.tests) pytest;
          pre-commit = mkGitHooksCheck system;
        }
      );

      devShells = forAllSystems (
        system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
          pythonSet = pythonSets.${system}.overrideScope editableOverlay;
          virtualenv = pythonSet.mkVirtualEnv "hokusai-dev-env" workspace.deps.all;
        in
        {
          default = pkgs.mkShell {
            packages = [
              virtualenv
              pkgs.uv
            ];
            env = {
              UV_NO_SYNC = "1";
              UV_PYTHON = pythonSet.python.interpreter;
              UV_PYTHON_DOWNLOADS = "never";
            };
            shellHook = ''
              unset PYTHONPATH
              export REPO_ROOT=$(git rev-parse --show-toplevel)
              ${(mkGitHooksCheck system).shellHook}
            '';
          };
        }
      );
    };
}